I2C tests ongoing
[dtplug] / lpc_link_lpc1764.ld
1 /*
2  * C linker script file for LPC1764
3  */
5 MEMORY
6 {
7         sram (rwx) : ORIGIN = 0x10000000, LENGTH = 16k
8         ahb_sram (rwx) : ORIGIN = 0x2007C000, LENGTH = 16k
9         flash (rx) : ORIGIN = 0x00000000, LENGTH = 128k
10 }
12 _sram_size = 16k;
13 _sram_base = 0x10000000;
14 /* Leave 32 bytes for IAP functions, see UM10360 Chapter 32, section 32.3.2.7 */
15 _end_stack = (_sram_base + _sram_size - 32);
17 ENTRY(Reset_Handler)
19 SECTIONS {
20         . = ORIGIN(flash);
22         .text :
23         {
24                 FILL(0xFF);
25                 KEEP(*(.vectors))
26                 *(.text.Reset_Handler .text.SystemInit)
27                 . = 0x000002FC;
28                 KEEP(*(.crp))
29                 *(.text*)
30                 *(.rodata*)
31                 *(.got*)
32                 _end_text = .;
33         } >flash
35         . = ALIGN(4);
37         .data :
38         {
39                 _start_data = .;
40                 *(.data*)
41                 _end_data = .;
42         } >sram AT >flash
44         . = ALIGN(4);
46         .bss :
47         {
48                 _start_bss = .;
49                 *(.bss*)
50                 *(COMMON)
51                 _end_bss = .;
52         } >sram
55         . = ALIGN(4);
56 }
58 _end = .;
59 PROVIDE(end = .);