git.techno-innov.fr Git - lpc11u3x/blob - lpc_link_lpc11u35.ld

   1 /*
   2  * C linker script file for LPC1224
   3  */
   4
   5 MEMORY
   6 {
   7         sram0 (rwx) : ORIGIN = 0x10000000, LENGTH = 8k
   8         sram1 (rwx) : ORIGIN = 0x20000000, LENGTH = 2k
   9         sram_usb (rwx) : ORIGIN = 0x20004000, LENGTH = 2k
  10         flash (rx) : ORIGIN = 0x00000000, LENGTH = 64k
  11 }
  12
  13 _sram_size = 8k;
  14 _sram_base = 0x10000000;
  15 /* Leave 32 bytes for IAP functions, see UM10462 Chapter 20, section 20.8.9 */
  16 _end_stack = (_sram_base + _sram_size - 32);
  17
  18 ENTRY(Reset_Handler)
  19
  20 SECTIONS {
  21         . = ORIGIN(flash);
  22
  23         .text :
  24         {
  25                 FILL(0xFF);
  26                 KEEP(*(.vectors))
  27                 *(.text.Reset_Handler .text.SystemInit)
  28                 . = 0x000002FC;
  29                 KEEP(*(.crp))
  30                 *(.text*)
  31                 *(.rodata*)
  32                 *(.got*)
  33                 _end_text = .;
  34         } >flash
  35
  36         . = ALIGN(4);
  37
  38         .data :
  39         {
  40                 _start_data = .;
  41                 *(.data*)
  42                 _end_data = .;
  43         } >sram0 AT >flash
  44
  45         . = ALIGN(4);
  46
  47         .bss :
  48         {
  49                 _start_bss = .;
  50                 *(.bss*)
  51                 *(COMMON)
  52                 _end_bss = .;
  53         } >sram0
  54
  55         . = ALIGN(4);
  56 }
  57
  58 _end = .;
  59 PROVIDE(end = .);